mirror of
https://github.com/spantaleev/matrix-docker-ansible-deploy.git
synced 2025-10-30 06:47:56 +01:00
3e84e354a8
It should be noted that this cannot be used for the initial install of services which require a database or have other dependencies. Those would typically need to invoke the playbook with `--tags=install-postgres,install-SERVICE`, etc. The purpose of this shortcut is to easily rebuild and restart a single serice subsequently. For those cases, often times there's no need to reinitialize the database and other components and simply running a single component's tasks is enough.
49 lines
1.9 KiB
Makefile
49 lines
1.9 KiB
Makefile
# Shows help
|
|
default:
|
|
@just --list --justfile {{ justfile() }}
|
|
|
|
# Pulls external Ansible roles
|
|
roles:
|
|
rm -rf roles/galaxy
|
|
ansible-galaxy install -r requirements.yml -p roles/galaxy/ --force
|
|
|
|
# Runs ansible-lint against all roles in the playbook
|
|
lint:
|
|
ansible-lint
|
|
|
|
# Runs the playbook with --tags=install-all,ensure-matrix-users-created,start and optional arguments
|
|
install-all *extra_args: (run-tags "install-all,ensure-matrix-users-created,start" extra_args)
|
|
|
|
# Runs installation tasks for a single service
|
|
install-service service:
|
|
just --justfile {{ justfile() }} run --tags=install-{{ service }},start-group --extra-vars=group={{ service }}
|
|
|
|
# Runs the playbook with --tags=setup-all,ensure-matrix-users-created,start and optional arguments
|
|
setup-all *extra_args: (run-tags "setup-all,ensure-matrix-users-created,start" extra_args)
|
|
|
|
# Runs the playbook with the given list of arguments
|
|
run +extra_args:
|
|
time ansible-playbook -i inventory/hosts setup.yml {{ extra_args }}
|
|
|
|
# Runs the playbook with the given list of comma-separated tags and optional arguments
|
|
run-tags tags *extra_args:
|
|
just --justfile {{ justfile() }} run --tags={{ tags }} {{ extra_args }}
|
|
|
|
# Runs the playbook in user-registration mode
|
|
register-user username password admin_yes_or_no *extra_args:
|
|
time ansible-playbook -i inventory/hosts setup.yml --tags=register-user --extra-vars="username={{ username }} password={{ password }} admin={{ admin_yes_or_no }}" {{ extra_args }}
|
|
|
|
# Starts all services
|
|
start-all *extra_args: (run-tags "start-all" extra_args)
|
|
|
|
# Starts a specific service group
|
|
start-group group *extra_args:
|
|
@just --justfile {{ justfile() }} run-tags start-group --extra-vars="group={{ group }}" {{ extra_args }}
|
|
|
|
# Stops all services
|
|
stop-all *extra_args: (run-tags "stop-all" extra_args)
|
|
|
|
# Stops a specific service group
|
|
stop-group group *extra_args:
|
|
@just --justfile {{ justfile() }} run-tags stop-group --extra-vars="group={{ group }}" {{ extra_args }}
|